cbmodule-photogallery/ModuleConfig.cfc at master · Computer-Know-how/cbmodule-photogallery · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
/**
* A module that will generate photo galleries for your ContentBox website,
* used in combination with the PhotoGallery widget.
*/
component {

	// Module Properties
	this.title 				= "Photo Gallery";
	this.author 			= "Computer Know How, LLC";
	this.webURL 			= "http://www.compknowhow.com";
	this.description 		= "A photo gallery for your ContentBox website";
	this.version			= "1.1";
	// If true, looks for views in the parent first, if not found, then in the module. Else vice-versa
	this.viewParentLookup 	= true;
	// If true, looks for layouts in the parent first, if not found, then in module. Else vice-versa
	this.layoutParentLookup = true;
	// Module Entry Point
	this.entryPoint			= "photoGallery";

	function configure(){

		// module settings - stored in modules.name.settings
		settings = {
			galleryFolders = "",
			allowedPhotoExtensions = "jpg,jpeg,bmp,gif,png",
			galleryTempFolderName = "_photogallery",
			gallerySmallFolderName = "small",
			galleryNormalFolderName = "normal",
			moveOriginals = true,
			galleryOriginalFolderName = "original",
			conventionGalleryPath = "_photogalleries",
			imageSize = {
				small = {
					resizeWidth = 150,
					resizeHeight = 150,
					cropWidth = 150,
					cropHeight = 150
				},
				normal = {
					resizeWidth = 600,
					resizeHeight = 600,
					cropWidth = 0,
					cropHeight = 0
				}
			},
			maxPhotosPerPage = 8
		};

		// SES Routes
		routes = [
			{pattern="/", handler="gallery",action="index"},
			// Convention Route
			{pattern="/:handler/:action?"}
		];

		// Interceptors
		interceptors = [
			{ class="#moduleMapping#.interceptors.FileBrowser", properties={ entryPoint="cbadmin" }, name="FileBrowser@PhotoGallery" }
		];

	}

	/**
	* Fired when the module is registered and activated.
	*/
	function onLoad(){
		// ContentBox loading
		if( structKeyExists( controller.getSetting("modules"), "contentbox" ) ){
			var menuService = controller.getWireBox().getInstance("AdminMenuService@contentbox");

			// Add the 'Photo Gallery' contribution to the module menu
			menuService.addSubMenu(topMenu=menuService.MODULES,name="PhotoGallery",label="Photo Gallery",href="#menuService.buildModuleLink('PhotoGallery','gallery.index')#");
		}
	}

	/**
	* Fired when the module is activated
	*/
	function onActivate(){
		var settingService = controller.getWireBox().getInstance("SettingService@contentbox");

		// Store default settings
		var findArgs = {name="photo_gallery"};
		var setting = settingService.findWhere(criteria=findArgs);
		if( isNull(setting) ){
			var args = {name="photo_gallery", value=serializeJSON( settings )};
			var photoGallerySettings = settingService.new(properties=args);
			settingService.save( photoGallerySettings );
		}

		// Flush the settings cache so our new settings are reflected
		settingService.flushSettingsCache();
	}

	/**
	* Fired when the module is unregistered and unloaded
	*/
	function onUnload(){
		// ContentBox unloading
		if( structKeyExists( controller.getSetting("modules"), "contentbox" ) ){
			var menuService = controller.getWireBox().getInstance("AdminMenuService@contentbox");

			// Remove the 'Photo Gallery' contribution from the module menu
			menuService.removeSubMenu(topMenu=menuService.MODULES,name="PhotoGallery");
		}
	}

	/**
	* Fired when the module is deactivated by ContentBox Only
	*/
	function onDeactivate(){
		var settingService = controller.getWireBox().getInstance("SettingService@contentbox");

		var args = {name="photo_gallery"};
		var setting = settingService.findWhere(criteria=args);
		if( !isNull(setting) ){
			settingService.delete( setting );
		}

		// Flush the settings cache so our new settings are reflected
		settingService.flushSettingsCache();
	}

}