remote-text-server/default.nix at main · Remote-Text/remote-text-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
{ lib
, rustPlatform
, pkg-config
, libgit2
, openssl
, zlib
, stdenv
, darwin
, pandoc
, texlive
, makeWrapper
}:

let
  package = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package;
in
rustPlatform.buildRustPackage rec {
  pname = package.name;
  version = package.version;

  src = ./.;

  cargoHash = "sha256-5lfLAy/rxUMde2ffvcFNBa9AbMfi61eS6INKWk+qe7o=";

  nativeBuildInputs = [
    pkg-config
  ];

  buildInputs = [
    libgit2
    openssl
    zlib
    makeWrapper
  ] ++ lib.optionals stdenv.isDarwin [
    darwin.apple_sdk.frameworks.IOKit
    darwin.apple_sdk.frameworks.Security
  ];

  postFixup = ''
    wrapProgram $out/bin/remote-text-server \
      --set PATH ${lib.makeBinPath [
        pandoc
        texlive
      ]}
  '';

  env = {
    OPENSSL_NO_VENDOR = true;
    VERGEN_IDEMPOTENT = true;
  };

  meta = with lib; {
    description = "The server-side software for Remote Text";
    homepage = "https://github.com/Remote-Text/remote-text-server";
    # license = with licenses; [ ];
    # maintainers = with maintainers; [ ];
  };
}