root-core/flake.nix at master · paulwalker-dev/root-core · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
{
  description = "A basic flake with a shell";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
      in
      rec {
        packages = {
          root-core = pkgs.mkYarnPackage rec {
            name = "root-core";
            src = ./.;
            packageJSON = ./package.json;

            distPhase = "true";
            buildPhase = ''
              yarn build
            '';

            postInstall = ''
              cp -r $out/libexec/${name}/deps/${name}/dist $out
            '';
          };

          container =
            let
              lighttpdConf = pkgs.writeText "lighttpd.conf" ''
                server.document-root = "${packages.root-core}/dist"
                server.port = 3000

                mimetype.assign = (
                  ".html" => "text/html"
                )
              '';
            in
            pkgs.dockerTools.buildImage {
              name = "website";
              tag = "latest";
              config = {
                Cmd = [ "${pkgs.lighttpd}/bin/lighttpd" "-D" "-f" "${lighttpdConf}" ];
              };
            };
        };

        defaultPackage = packages.root-core;

        devShell = pkgs.mkShell {
          buildInputs = [ ];
          nativeBuildInputs = with pkgs; [
            # Node
            nodejs
            yarn

            # Formatting
            nixpkgs-fmt
            nodePackages.prettier
          ];
        };
      });
}